Volume Spread Analysis

 [citation

=" Wyckoff Supply & Demand CMD This has now been coded using various sources of Volume Spread Analysis - Undeclared Secrets and Master of the Markets by Tom Williams, and Master Class 4/4/2010, and Trading in the Shadow of Smart Money Vol2 (TSSM), and That was the week that was by Tom Williams. VSA is largely judgemental.  The threshold weightings below allow my interpreatation for the Bullchart coding  CMD"]

{In summary there may be a number of indicators for each of these

Principles of weakness

1 End of rising market

2 No Demand at Market Top

3 No Result from effort

4 Upthrusts

5 No Demand on Downtrend

6 Widespread down through previous support

7 Buying Climax

8 Top Reversal

Principles of Strength

1 Bottom Reversal

2 Stopping Volume

3 Tests

4 Absorption

5 Bagholding

6 Selling Climax

7 Shakeout

8 No Supply in a rising market}

{-------------------------------------------------------------------------------------------------------}

{ The selection of an appropriate trend calculation method is most critical as many SOS and SOW indicators depend on whther trend is up or down.}

[target=Price]

Vib:=input("Vibration", 4, .001, 100);

Z:=Zig(If(Outside() AND Ref(H,-1)>Ref(H,-2),H,If(Outside() AND Ref(L,-1)<Ref(L,-2),L,If((Outside() OR Inside()) AND C>O,H,If((Outside() OR Inside()) AND O>C,L,If(H>Ref(H,-1),H,If(L<Ref(L,-1),L,If(Ref(H,-1)>Ref(H,-2),H,If(Ref(L,-1)<Ref(L,-2),L,C)))))))),Vib,%);

Trendup:=Z>ref(z,-1);

Trenddown:=Z<=ref(z,-1);

{-------------------------------------------------------------------------------------------------------}

prd1:=input("Period for  Volume MA", 30, 1, 200);

prd2:=input("Period for Total Spread MA", 200, 1, 200);

Cut:=input("Narrow Spread Cut off", 0.5, .05, 0.8);

Cut2:=input("UltraWS Cut off", 1.2, .05, 2.0);

method := inputma("Method",SIMPLE);

THExLo:=input("Extreme Low Vol Maximum Threshold", 0.70, .1, 2);

THLo:=input("Maximum for Low Vol Threshold", 1.0, .1, 2);

THNo:=input("Ultra High Minimum Vol Threshold", 1.3, .1, 2.00);

Uf:=input("Upthrust % on previous High", 1.0005, .05, 2.0);

Tf:=input("Test decline factor", 0.9995, .05, 2.0);

Range := H - L;

ExtremeLowVol:=If(V<=THExLo*ma(V,prd1,s),V,0);

LowVol:=If(V>THExLo* ma(V,prd1,s) and V<=THLo*ma(V,prd1,s), V, 0);

HighVol:=If(V>THLo* ma(V,prd1,s) and V<=THNo*ma(V,prd1,s), V,0) ;

UltraHighVol:=If(V>THNo*ma(V,prd1,s),V,0);

Upbar:=   C>Hist(C,1);

Levelbar:=Hist(C,1);  {used for TW Easy Trend rules}

Downbar:= C< Hist (C,1);

GapUp:=L>= Hist (H,1);

GapDown:=H<= Hist (L,1);

NS:=(Range<=Cut*ma(Range,prd2,method));

WS:=(Range>Cut*ma(Range,prd2,method) ) and (Range<Cut2* ma(Range,prd2,method));

UltraWS:=(Range>=Cut2*ma(Range,prd2,method) );

UltraBear:=C<=((Range*0.2)+L);

Bear:=C>((Range*0.2)+L) AND C<=((Range*0.50)+L);

Bull:=C>((Range*0.50)+L) AND C<=((Range*0.80)+L);

UltraBull:=C>((Range*0.80)+L);

{SOS 1 Bottom Reversal}

SOS1:=

If ( (TrendDown OR (Trendup and Hist(c,1)<Hist(c,15)))

AND L<Hist(L,1)

AND Ultrabull

AND (upbar or C=Hist(c,1))

AND (Hist(Bull,1) OR Hist(Bear,1) OR Hist(Ultrabear,1))

AND (WS OR UltraWS) {Distinguish from version 1a}

AND (HighVol OR Ultrahighvol)

AND (Hist(C,1)<=Hist(C,2) AND Hist(C,1)<=Hist(C,3) AND Hist(C,1)<=Hist(C,4) AND Hist(C,1)<=Hist(C,5))

AND (Hist(L,1)<=Hist(L,2) AND Hist(L,1)<=Hist(L,3) AND Hist(L,1)<=Hist(L,4) AND Hist(L,1)<=Hist(L,5)),1,0);

[name=1 brS; linestyle=marker; marker=long; fontsize=8; tooltip="SOS 1 Bottom Reversal - based on two bars a variety of versions. Second bar is rapidly marked up to lock in traders that shorted or to lock you out if you want to buy the market.  People hesitate buying as the shares look expensive relative to yesterday. 

THIS VERSION HAS HIGH VOLUME INDICATING SUPPLY IS STILL PRESENT. We can expect the market to come back down within a few days to test to see if supply has dried up.  (See SOS1a There is high volume on the second day it indicates supply and we can expect the market to come back down within a few days to test to see if supply has dried up).  Gavin Holmes Trading in theShadow of the Smart Money78,79,97.";];

SOS1;

{SOW 1S End of Rising Market.  Similar to SOW 81b Selling Pressure.  Per TW 061110 Markets TOP OUT on NS upbars}

SOW1S:=

If(H=Highest(H,25)

AND TrendUP

AND (Upbar Or C=Hist(c,1))

AND UltraHighVol {Vol =Supply Or See V2 Extreme low Vol No Demand}

AND (NS OR WS) {Added WS as some TG NS indicators were not getting picked up}

{Added Ultrabull as TG indicators sometimes show close=High}

AND (Ultrabear OR Bear ),1,0);

[name=1 ermSup;  marker=short;  fontsize=8; tooltip="SOW 1S End of rising market Supply - Don't see too often Fresh new ground to the left is not 10 bars but 2 to 3 months or a year per Tom Williams.  Gavin Holmes uses 500 bars

Psychology: a) Uptrend to the left into fresh new ground.  . b) GapUp in the morning is a strong sign but some variations have no Gap Up c)SM is selling to satisfy surges of demand hence putting a cap on higher prices and the NS. d) Buy orders are being rapidly satisfied. If SM had been buying there would be a wide spread f)the Close does not make a difference what counts is the NS g) Ultrahighvol.  This is a serious sign of weakness

Gavin conservative approach Follow Up:Wait for market to mushroom over if you are going to short.  Mkt should make lower highs each day.  Wait for at least 10 bars in any time frame to see the result of weakness. TW would jump[ in.

In strong down trend there should be increasing vol on Down bars and decreasing Vol on Up bars.  Wait for a No Demand up bar, an upthrust on either high or low volume in order to short.  The end of a down trend is often 2 consecutive Up bars followed by a Test or No Supply Down bar. TSSM 5,14,21,22,23,24,30,71 ";];

SOW1S;

{-------------------------------------------------------------------------------------------}

{This section takes up price colour bars equal to Volume bars for VSA codes}

{ Volume Spread Analysis

[description="VSA Volume Indicator CMD"]}

[target=Price; linestyle=PriceColor]

[name=Low Vol; Color=Lime Green] { Low volume}

LowVol;

[name=High Vol; Color=Dark Violet] { High Volume climax}

HighVol;

[name=Ultra High Vol; Color=Red] { Ultra High Volume}

UltraHighVol;

[name=Extreme Low Vol; Color=Orange] {Extremely Low Volume}

ExtremeLowVol;

{End of Indicator 1 }

{ Volume Spread Analysis Colour Volume Bars }

[description="VSA VOLUME Bars Colours adj weightings "]

prd1:=input("Period for MAs", 50, 1, 200);

THExLo:=input("Extreme Low Maximum Threshold", 0.7, .1, 2);

THLo:=input("Maximum for Low Threshold", 1.0, .1, 2);

THNo:=input("Extreme High Minimum Threshold",1.3, .1, 2);

Range := High - Low;

Value1 := Volume;

[linestyle=Bar; width=4]

{[name=Normal Vol; Color=Gray] { Normal }

Volume;}

[name=Extreme Low Vol;Color=Orange] {Extremely Low Volume}

If(Value1 <=THExLo*ma(V,prd1,s),V,0);

[name=Low Vol;Color=Lime Green] { Low volume}

If(Value1 >THExLo* ma(V,prd1,s) and v <=THLo*ma(V,prd1,s), V, 0);

[name=High Vol;Color=Dark Violet] { High Volume climax}

If(Value1 >THLo* ma(V,prd1,s) and v<=THNo*ma(V,prd1,s), V,0) ;

[name=Ultra High Vol;Color=Red] { Ultra High Volume}

If(Value1 >THNo*ma(V,prd1,s),V,0);